汇编语言编写电子秒表代码

Question

有四个控制键，开始，停止，继续，返回

Answer 1

秒表可以用定时器来实现，举例如下：

KEYVAL EQU 30H

DAT EQU 33H

SCANLED EQU 39H

CLK EQU 77H

SEC EQU 78H

SEC1 EQU 79H

SEC2 EQU 7AH

DOT BIT 00H

ORG 0000H

LJMP MAIN

ORG 0003H

LJMP EXTINT0

ORG 000BH

LJMP T0ISR ;50ms定时

ORG 001BH

LJMP T1ISR ;扫描显示

ORG 0030H

MAIN:

MOV SP,#5FH

MOV TMOD,#11H

MOV TH0,#03CH

MOV TL0,#0B0H

MOV TH1,#0ECH

MOV TL1,#078H

MOV KEYVAL,#2

MOV 33H,#10H

MOV 34H,#10H

MOV 35H,#10H

MOV 36H,#10H

MOV CLK,#0

SETB IT0

SETB EX0

CLR TR0

CLR ET0

MOV R2,#0

SETB TR1

SETB ET1

SETB EA

LOOP:

MOV A,KEYVAL

LOOP1:

JNZ LOOP2 ;启动

SETB TR0

SETB ET0

SJMP LOOP

LOOP2:

DEC A

JNZ LOOP3 ;暂停

CLR TR0

CLR ET0

SJMP LOOP

LOOP3:

DEC A

JNZ LOOP ;清零

MOV 36H,#0

MOV 35H,#0

MOV 34H,#0

MOV 33H,#0

SJMP LOOP

EXTINT0:

PUSH ACC

INC KEYVAL

MOV A,KEYVAL

CJNE A,#3,EXT00

EXT00:

JC EXT01

MOV KEYVAL,#0

EXT01:

POP ACC

RETI

T0ISR:

PUSH ACC

CLR TR0

MOV TH0,#3CH

MOV TL0,#0B0H

SETB TR0

INC CLK

MOV A,CLK

CJNE A,#2,T0ISRE

MOV CLK,#0

INC 36H

MOV A,36H

CJNE A,#10,T0ISRE

MOV 36H,#0

INC 35H

MOV A,35H

CJNE A,#10,T0ISRE

MOV 35H,#0

INC 34H

MOV A,34H

CJNE A,#6,T0ISRE

MOV 34H,#0

INC 33H

MOV A,33H

CJNE A,#10,T0ISRE

MOV 33H,#0

T0ISRE:

POP ACC

RETI

T1ISR:

PUSH ACC

CLR TR1

MOV TH1,#0ECH

MOV TL1,#78H

SETB TR1

MOV DPTR,#LEDTAB

T100:

MOV R0,#DAT

MOV A,SCANLED

ADD A,R0

MOV R0,A

MOV A,SCANLED

JNZ T101

MOV P2,#01H

SETB DOT

SJMP T1DIS

T101:

DEC A

JNZ T102

MOV P2,#02H

CLR DOT

SJMP T1DIS

T102:

DEC A

JNZ T103

MOV P2,#04H

SETB DOT

SJMP T1DIS

T103:

MOV P2,#08H

CLR DOT

T1DIS:

MOV A,@R0

MOVC A,@A+DPTR

JNB DOT,T1DIS1

ORL A,#01H

T1DIS1:

CPL A

MOV P0,A

INC SCANLED

MOV A,SCANLED

CJNE A,#4,T1END

MOV SCANLED,#0

T1END:

POP ACC

RETI

LEDTAB: DB 0FCH ;"0" 00H

DB 60H ;"1" 01H

DB 0DAH ;"2" 02H

DB 0F2H ;"3" 03H

DB 66H ;"4" 04H

DB 0B6H ;"5" 05H

DB 0BEH ;"6" 06H

DB 0E0H ;"7" 07H

DB 0FEH ;"8" 08H

DB 0F6H ;"9" 09H

DB 0EEH ;"A" 0AH

DB 3EH ;"B" 0BH

DB 9CH ;"C" 0CH

DB 7AH ;"D" 0DH

DB 9EH ;"E" 0EH

DB 8EH ;"F" 0FH

DB 00H ;" " 10H

END

Answer 2

这个是我们老师给的，两个控制键控制四种状态，一个开关控制开始/清零，一个开关控制停止/继续，希望对LZ有用：
ORG 0000H
LJMP START
ORG 000BH
LJMP TT0
ORG 0030H
START:
MOV 43H,#0
MOV 42H,#0
MOV 41H,#0
MOV 40H,#0
SETB EA
SETB ET0
MOV TMOD,#00000001B
MOV TH0,#0D8H
MOV TL0,#0F0H
MAIN:
SETB P0.0
JB P0.0,QINGLING
MOV 43H,#0
MOV 42H,#0
MOV 41H,#0
MOV 40H,#0
CLR TR0
LJMP LOOP

QINGLING:
SETB P0.1
JNB P0.1,JIXU
CLR TR0
LJMP LOOP

JIXU:
SETB TR0
LOOP:
LCALL TIAOZHENG
LCALL XIANSHI
LJMP MAIN

TIAOZHENG:
MOV A,40H
CJNE A,#10,FANHUI
INC 41H
MOV 40H,#0
MOV A,41H
CJNE A,#10,FANHUI
INC 42H
MOV 41H,#0
MOV A,42H
CJNE A,#10,FANHUI
INC 43H
MOV 42H,#0
MOV A,43H
CJNE A,#10,FANHUI
MOV 43H,#0
FANHUI:
RET

XIANSHI:
MOV DPTR,#TAB
MOV A,40H
MOVC A,@A+DPTR
MOV P1,A
MOV P2,#11111110B
;LCALL DELAY
MOV P2,#11111111B

MOV A,41H
MOVC A,@A+DPTR
MOV P1,A
MOV P2,#11111101B
;LCALL DELAY
MOV P2,#11111111B

MOV A,42H
MOVC A,@A+DPTR
ANL A,#11111110B
MOV P1,A
MOV P2,#11111011B
;LCALL DELAY
MOV P2,#11111111B

MOV A,43H
MOVC A,@A+DPTR
MOV P1,A
MOV P2,#11110111B
;LCALL DELAY
MOV P2,#11111111B
RET

TT0:
INC 40H
MOV TH0,#0D8H
MOV TL0,#0F0H
RETI

TAB:
DB 03H 9FH 25H 0DH 99H 49H 41H 1FH 01H 09H本回答被网友采纳